Altitude Data Reduction

« Appendix

E.1 Sample Program

0010 REM TRACK.BAS by Geoff Landis
0020 REM from the 9 / 83 "Model Rocketeer" page 11
0030 REM NAR Tracking Data Reduction by various methods
0040 REM Refer to that issue for full details
0050 REM
0060 REM Tracking Data Reduction Program
0070 REM Program Copyright (C) 1983
0080 REM by Geoffrey A. Landis
0090 REM may be freely used but not sold
0100 REM
0110 REM Minor Edits and Renumbering Copyright (C) 1985 Robert G. Kaplow
0150 REM
0200 REM data input 
0210 REM Change the next line as appropriate for your baseline
0220 B = 300.
0240 R1 = .0174532925199433
0500 PRINT
0510 PRINT "Tracker One Azimuth, Elevation: "
0520 INPUT A1, E1
0530 PRINT "Tracker Two Azimuth, Elevation: "
0540 INPUT A2, E2
0550 IF E1 < 0. THEN 9998
0560 IF E2 < 0. THEN 9998
0570 A1 = A1 * R1
0580 E1 = E1 * R1
0590 A2 = A2 * R1
0600 E2 = E2 * R1
1000 REM
1010 REM Geodesic Data Reduction
1020 REM
1030 F = SIN(E1) * SIN(E2) - COS(E1) * COS(E2) * ( COS(A1) * COS(A2) - SIN(A1) * SIN(A2) )
1040 D = 1. - F ^ 2
1050 T = ( COS(E2) * SIN(E1) * SIN(A2) - COS(E1) * SIN(E2) * SIN(A1)) / SQR(D)
1060 D1 = ( COS(E1) * COS(A1) + F * COS(E2) * COS(A2) ) / D
1070 D2 = ( COS(E2) * COS(A2) + F * COS(E1) * COS(A1) ) / D
1080 A = B * ( SIN(E1) + SIN(E2) ) * ( D1 * D2 ) / ( D1 + D2 )
1090 C = ABS ( T * B / A ) * 100.
1100 PRINT
1110 PRINT "Geodesic"
1120 GOSUB 9000
2000 REM
2010 REM Vertical Midpoint Data Reduction
2020 REM
2030 S = SIN(A1 + A2)
2040 H1 = SIN(A2) * SIN(E1) / ( S * COS(E1) )
2050 H2 = SIN(A1) * SIN(E2) / ( S * COS(E2) )
2060 A = B * ( H1 + H2 ) / 2.
2070 C = ABS ( ( H1 - H2 ) / ( H1 + H2 ) ) * 100.
2080 PRINT
2090 PRINT "Vertical Midpoint"
2100 GOSUB 9000
2110 REM
8999 GO TO 500
9000 REM
9010 REM Display Altitude and Closure
9020 REM
9030 PRINT "Altitude: "; A
9040 IF C > 10. THEN GO TO 9080
9050 IF A < 1. THEN GO TO 9080
9060 PRINT "Track Closed: "; C; "%"
9070 RETURN
9080 PRINT "Track Not Closed: "; C; "%"
9090 RETURN
9998 STOP
9999 END

E.2 Sample Test Data

East West Geodesic Vertical Midpoint
Azimuth Elevation Azimuth Elevation Altitude Closure Altitude Closure
90 45 50 40 380.0 6.3% 374.6 4.6%
30 45 60 45 203.3 31.2% 204.9 26.8%
120 75 25 55 596.3 6.2% 735.9 12.1%
30 80 40 85 1337.8 3.2% 1494.2 22.1%

All altitudes in meters. Test cases assume 300-meter baseline.

E.3 Symbols used in Equations
B is the length of the tracking baseline.
A1 and E1 are the azimuth and elevation angles reported by tracking east.
A2 and E2 are the azimuth and elevation angles reported by tracking west.
A is the final, reduced altitude.
C is the closure, expressed as a fraction of the altitude. Closure <= 0.1 denotes a closed track.
Other symbols denote common subexpressions, and are used solely for purposes of clarity.

E.4 Vertical Midpoint Method

vmid

 

E.5 Geodesic Method

geodesic